// Darstellung von Flächen 2. Ordnung   (zweischaliges Hyperboloid)
// A. Filler, Humboldt-Universitaet zu Berlin, 2002
// ---------------------------------------------------------------
#version 3.5;                         // benötigte POV-Ray-Version
#include "colors.inc"                 // Definition der Farben
background {White}                    // Farbe des Hintergrunds

// ---------------------------------------------------------------
// Darstellung von Flaechen, die durch implizite Gleichungen gegeben sind
// ---------------------------------------------------------------
isosurface {

  function { - 3*x*x + 2*y*y - 3*z*z - 0.25 }  // implizite Gleichung der Fläche    

  contained_by { box { -1.8, 1.8 } }  
  accuracy 0.01   max_gradient 20                      
  open                             
texture { pigment { Red }  
 finish {phong 1.0 phong_size 20 ambient 0.2 diffuse 0.8 }    }
 no_shadow
}

// ---------------------------------------------------------------
#declare intervall = 1.75 ;             // Diese Variable legt den Bildausschnitt der gesamten Szene fest.
// ---------------------------------------------------------------
// Einfügen eines Koordinatensystems mit Achsen von -intervall bis intervall
// (definiert in "ana-geo.inc")
// ---------------------------------------------------------------
// Definition der Kamera und der Lichtquellen

#declare winkel =  - 60  - 1.2*clock ;       // Winkel der Kamera zur x-Achse (in Grad)
camera { orthographic
         location  <60*intervall*cos(winkel*pi/180), 20*intervall, 60*intervall*sin(winkel*pi/180)>
         right x*4/3*2.6*intervall   up y*2.6*intervall
         look_at   <0.0, 0,  0.0> 
}
light_source { <5*intervall, 0.2*intervall, 0>  color rgb <1, 1, 1> }
light_source { <0,10*intervall,2*intervall>  color rgb <1, 1, 1> }
// ---------------------------------------------------------------------------