// Darstellung einer Konischen Spirale durch ihre Parameterdarstellung
// A. Filler, Humboldt-Universitaet zu Berlin, 2002
// ---------------------------------------------------------------
#version 3.5;                         // benötigte POV-Ray-Version
#include "colors.inc"                 // Defintion der Farben
background {White}                    // Farbe des Hintergrundes

// Parameterdarstellung der Konischen Spirale
//   ("parametric object")
parametric {
  function {u*v*sin(15*v)}
  function {v}
  function {u*v*cos(15*v)}
  <0,-1>,<1,1>                        // Intervall für u und v
  contained_by { box { <-1,-1,-1>, <1,1,1> } }  
  max_gradient 10   accuracy 0.0005   // Berechnungsparameter
  precompute 18 x,y,z                 // Berechnungsparameter
 texture{ pigment{rgb<0.4,0.4,0.4>} 
    finish{ ambient 0.4  diffuse 0.6  phong 0.5  reflection 0.1}    } 
}

// Definition der Kamera und der Lichtquellen

#declare intervall = 2.8  ;   // Diese Variable legt den Bildausschnitt fest.
#declare winkel =  - 30 ;     // Winkel der Kamera zur x-Achse (in Grad)

// Auf die beiden Parameter "intervall" und "winkel" koennte verzichtet werden, dafuer muessten unten die entsprechenden
// Werte 10 und -60 dann jeweils direkt eingesetzt werden. Allerdings kann man durch die zentrale Definiton dieser Werte 
// leicht den Bildausschnitt und den Blickwinkel veraendern. 

camera { orthographic
         location  <60*intervall*cos(winkel*pi/180), 20*intervall, 60*intervall*sin(winkel*pi/180)>
         right x*4/3*intervall   up y*intervall
         look_at   <0.0, -intervall/10,  0.0> 
}
light_source { <2.5*intervall, 2*intervall, -5*intervall>  color rgb <1, 1, 1> }
light_source { <0,10*intervall,2*intervall>  color rgb <1, 1, 1> }
light_source { <60*intervall*cos(winkel*pi/180), 20*intervall, 60*intervall*sin(winkel*pi/180)>   color rgb <0, 0, 1>}